Lab 10 - Applications of Integration - Volume by Definite Integral.ipynb

Kernel: SageMath 9.2

Lab 10 - Applications of Integration: Volume by Definite Integral

Overview

The topic of Volume of Revolution is often difficult for students to grasp. With different methods, formulations, and rotating axes, this topic may appear confusing at first and adequate practice is a must. In this lab, we will introduce SageMath commands which will help you visualize Volume of Revolution problems.

Important SageMath Commands Introduced in this Lab

ParseError: KaTeX parse error: Undefined control sequence: \hfill at position 32: …|l|l|} \hline \̲h̲f̲i̲l̲l̲ ̲\textbf{Command…

Related Course Material

6.1 and 6.2

Example 1

Consider the solid formed by rotating the region between $y = x$ and $y = 2-x^2$ from $x=0$ to $x=1$ about the $x$-axis. We will use SageMath to plot this solid and then find its volume. First, we use the $\textbf{plot}(\dots)$ command to plot the region before it is rotated.

plot([x,2-x^2], xmin = 0, xmax = 1)

Next, we can use the ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 19: …xtbf{revolution_̲plot3d}(\textit… command to plot the solid formed by rotating this region about the $x$-axis.

p1 = revolution_plot3d(2-x^2, (x,0,1), parallel_axis = 'x', show_curve=True, opacity = .75)
p2 = revolution_plot3d(x, (x,0,1), parallel_axis = 'x', show_curve=True)
show(p1 + p2)

Now that we can see the solid, we can decide whether we should use the disk/washer method to find the volume, or the shell method. For this example, it is easier to use the disk/washer method since we can find the volume with a single integral. Since there is some open space in our solid, we need to use the washer method. Recall that the formula for calculating the volume using the washer method is $$V = \pi\int_a^b (R(x)^2 - r(x)^2) \ dx,$$ where $R(x)$ is the top function and $r(x)$ is the bottom function. In this example, we have that $R(x) = 2 - x^2$ and $r(x) = x.$ We can use SageMath to calculate this volume using the $\textbf{integrate}(\dots)$ command from Lab 9.

def R(x):
    return 2 - x^2
def r(x):
    return x
show(pi * integrate(R(x)^2 - r(x)^2, x, 0, 1))

Therefore, the solid formed by rotating the region between $y = x$ and $y = 2-x^2$ from $x=0$ to $x=1$ about the $x$-axis has volume $\dfrac{38}{15}\pi.$

Example 2

Consider the solid formed by rotating the region between $y = \cos(x)$ and $y = \sin(x)$ from $x = 0$ to $x = \dfrac{\pi}{4}$ about the $y$-axis.

plot([cos(x), sin(x)], xmin = 0, xmax = pi/4)

This time, we are revolving the region around the $y$-axis. In order to do that, we need to omit the ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 17: …textit{parallel_̲axis = 'x'} from the ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 19: …xtbf{revolution_̲plot3d}(\dots) command.

p1 = revolution_plot3d(cos(x), (x,0,pi/4), show_curve=True, opacity = .75)
p2 = revolution_plot3d(sin(x), (x,0,pi/4), show_curve=True)
show(p1 + p2)

Now, we need to decide whether we should use the disk/washer method or the shell method. By looking at the solid, we can see that using rectangles which run parallel to the axis of revolution will result in only having to use a single integral to calculate the volume. Therefore, we will use the shell method. Recall that the formula for calculating the volume using the shell method is $$V = 2\pi\int_a^b r(x)h(x) \ dx,$$ where $r(x)$ is the distance that our generic rectangle is from the axis of revolution and $h(x)$ is the height of our generic rectangle. Since the axis of revolution is the $y$-axis, we have that $r(x) = x$. Since $\cos(x)$ is the top function and $\sin(x)$ is the bottom function in this region, we see that $h(x) = \cos(x) - \sin(x).$

def r(x):
    return x
def h(x):
    return cos(x) - sin(x)
show(2 * pi * integrate(r(x)*h(x), x, 0, pi/4))

Therefore, the solid formed by rotating the region between $y = \cos(x)$ and $y = \sin(x)$ from $x = 0$ to $x = \dfrac{\pi}{4}$ about the $y$-axis has volume $\dfrac{1}{2}\pi (\sqrt{2}\pi - 4).$

Example 3

Consider the solid formed by rotating the region in the first quadrant bounded between the functions $f(x) = x^3$ and $g(x) = 7x - 6$ about the $x$-axis. In order to plot this region, we need to determine the domain for the bounded region. Note that the endpoints of the bounded region are $x$-values such that $f(x) = g(x)$. We can use SageMath to find these values.

def f(x):
    return x^3
def g(x):
    return 7*x - 6
solve(f(x) == g(x), x)

Since we want the bounded region in the first quadrant, we use the domain $[1,2]$.

plot([f(x), g(x)], xmin = 1, xmax = 2)

p1 = revolution_plot3d(7*x-6, (x,1,2), parallel_axis = 'x', show_curve=True, rgbcolor=(1,0.5,0), opacity = .5)
p2 = revolution_plot3d(x^3, (x,1,2), parallel_axis = 'x', show_curve=True)
show(p1 + p2)

For this solid, we can calculate the volume using both the disk/washer method and the shell method. We will use both and verify that they give the same value. First, we will use the disk/washer method. Note that the top function is $R(x) = 7x - 6$ and the bottom function is $r(x) = x^3.$

def R(x):
    return 7*x - 6
def r(x):
    return x^3
show(pi * integrate(R(x)^2 - r(x)^2, x, 1, 2))

Now, we will use the shell method. Since we are using the shell method on a solid which was formed by rotating a region about the $x$-axis, we need to write the functions $f(x)$ and $g(x)$ in terms of $y$ instead of $x$. Note that $$y = f(x) = x^3 \implies x = f^{-1}(y) = y^{1/3}$$ and $$y = g(x) = 7x-6 \implies x = g^{-1}(y) = \dfrac{y + 6}{7}.$$ Also, we need to change the bounds $x=1$ and $x=2$ to be in terms of $y$. We can use either $f(x)$ or $g(x)$ to find the corresponding $y$-values.

print(f(1))
print(f(2))

Thus, our new bounds are $y = 1$ and $y = 8$. Note that from the perspective of the $y$-axis, $f^{-1}(y)$ is the top function and $g^{-1}(y)$ is the bottom function.

y = var('y')
def finv(y):
    return y^(1/3)
def ginv(y):
    return (y+6)/7
show(2 * pi * integrate(y * (finv(y) - ginv(y)), y, 1, 8))

Therefore, using either method, we found that the volume of the solid formed by rotating the region in the first quadrant bounded between $f(x)$ and $g(x)$ about the $x$-axis is $\dfrac{130}{21}\pi.$

Example 4

Find the volume formed by rotating the following regions about the $x$-axis.

1. $y = x^2, y = 2 - x, y = 0$

2. $y = \sqrt{x}, y = 2 - x, y = 0$

3. $y = \sqrt{x}, y = 2 - x, x = 0$

Example 5

Find the volume formed by rotating the following regions about the $y$-axis.

1. $y = 1/x, x = 2, y = 2$

2. $y = \sqrt{x}, y = 2 - x, y = 0$

3. $y = \sqrt{x}, y = 2 - x, x = 0$