Lab 03 - The u-Substitution Method.ipynb

Kernel: SageMath 9.2

Lab 03 - The u-Substitution Method

Overview

In this lab, we will use SageMath to perform u-substitutions for both indefinite and definite integrals.

Important SageMath Commands Introduced in this Lab

ParseError: KaTeX parse error: Undefined control sequence: \hfill at position 32: …|l|l|} \hline \̲h̲f̲i̲l̲l̲ ̲\textbf{Command…

Related Course Material

Section 5.5

Example 1

We will calculate the indefinite integral $\displaystyle \int x^2e^{x^3} \ dx$ by using u-substitution. First, we must decide what substitution to make. Since $x^3$ is the inside function and its derivate $3x^2$ appears in the integrand, up to a constant multiple, we should let $u = x^3.$ We can use SageMath to handle the u-substitution for us. We start by defining $f(x)$ as our integrand and $u$ as $x^3$ and then calculating $du$.

u = var('u')     ## This is to define u as a variable
assume(u>0)      ## This is to avoid any problems with the solve command
def f(x):
    return x^2 * e^(x^3)
sub = u == x^3     ## We write u == x^3 in order to tell SageMath that this is an equation
du = diff(sub.rhs(),x)  ## This defines du as the derivative of the right hand side of the equation, u = x^3, with respect to x

Now, we need to substitute both $u$ and $du$ into our original integral. In order to do this, we first need to solve for $u$ in terms of $x$. In this example, it can easily be done by hand to obtain $x = u^{1/3}.$ We can also use SageMath to obtain the same result using the $\textbf{solve}$ command.

solve(sub, x)

Note that SageMath returns both real and complex solutions to the equation $u = x^3$ when solving for $x$. The function ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 14: \textbf{solve_̲for_x} in the package ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 14: \textbf{uofsc_̲calculus_labs} will return the expected solution when solving the equation for $x$. To access this function, we must import it from the package by using the command $\textbf{from} \textit{ package } \textbf{import} \textit{ function}$.

from uofsc_calculus_labs import solve_for_x

If SageMath returns the error stating that there is no module named ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 14: \textbf{uofsc_̲caluculus_labs}, then you will first need to install the package using $\textbf{pip}$. This can be done in SageMath by running the command below.

$\textbf{Note: }$If you are using a lab computer or the Binder server, then you will not be able to use ParseError: KaTeX parse error: Unexpected end of input in a macro argument, expected '}' at end of input: \textbf{%pip}; however, ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 14: \textbf{uofsc_̲calculus_labs} should already be installed.

%pip install uofsc_calculus_labs

from uofsc_calculus_labs import solve_for_x

Once we have imported the function ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 14: \textbf{solve_̲for_x}, we use it to solve the equation for $x$.

solve_for_x(sub,x)

SageMath returns $x = u^{1/3}$ as desired. Now we can use SageMath to substitute both $u$ and $du$ into our original integral.

g(u) = (f(x)/du).substitute(solve_for_x(sub,x))
g(u)

Therfore, our new integrand is $\dfrac{1}{3}e^u$. We can have SageMath display the new integral by using the $\textbf{integrate}$ command along with the parameter $\textbf{hold = true}$ which will keep SageMath from evaluating the integral.

show(integrate(g(u),u,hold = true))

It follows that under the u-substitution $u = x^3$, we have $$\displaystyle \int x^2 e^{x^3} \ dx = \int \dfrac{1}{3} e^u \ du.$$ Now, we can integrate the right integral easily by hand. We see that $$\displaystyle \int \dfrac{1}{3} e^u \ du = \dfrac{1}{3} e^u + C.$$ Finally, we write our final answer back in terms of $x$ since that was our starting variable. Hence, we have that $$\displaystyle \int x^2 e^{x^3} \ dx = \dfrac{1}{3} e^{x^3} + C.$$

Example 2

Let us use u-substitition to evalaute $\displaystyle \int 2x(x^2 + 5)^{-4} \ dx$. We can again use SageMath to perform the u-substitution by repeating the steps in Example 1 with a new integrand $f(x)$ and new $u$. In order to save time for future examples, we can package all of the steps together into a function which we will call ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 10: \textbf{u_̲sub(f, sub)}.

def u_sub(f, sub): 
    u = var('u')
    assume(u>0)
    du = diff(sub.rhs(),x)
    g(u) = (f(x)/du).substitute(solve_for_x(sub,x)).expand()
    return show(integrate(g(u),u,hold = true))

Before we use ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 10: \textbf{u_̲sub} to solve our new problem, let's verify that it works by using it on the integral from Example 1.

def f(x):
    return x^2 * e^(x^3)
u_sub(f, u == x^3)

It works! Now let us try it with the integral $\displaystyle \int 2x(x^2 + 5)^{-4} \ dx$. We have that $f(x) = 2x(x^2 + 5)^{-4}$ and $u = x^2 + 5$. We now use ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 10: \textbf{u_̲sub} to rewrite the integral in terms of $u$.

def f(x):
    return 2*x*(x^2 + 5)^(-4)
u_sub(f, u == x^2 + 5)

Now, we should be able to integrate the new integral without much trouble and get $$\displaystyle \int \dfrac{1}{u^4} \ du = -\dfrac{1}{3u^3} + C.$$ To get our final answer, we replace $u$ with $x^2 + 5$ to get $$\displaystyle \int 2x(x^2 + 5)^{-4} \ dx = -\dfrac{1}{3(x^2 + 5)^3} + C.$$ We can check our final answer in SageMath by using the normal $\textbf{integrate}$ command. (Don't forget that SageMath does not include the $+ C$.)

show(integrate(f(x),x))

Example 3

Now suppose we wish to evaluate the definite integral $$\displaystyle \int_{-1}^1 3x^2\sqrt{x^3 + 1} \ dx.$$ We now not only need to rewrite the integrand in terms of $u$, we also have to change the bounds to be in terms of $u$. We can use a modified version of the ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 10: \textbf{u_̲sub} function above to accomplish this.

def u_sub_with_bounds(f, sub, a, b):
    u= var('u')
    assume(u>0)
    new_a = sub.rhs().substitute(x=a)     ## Rewrites a in terms of u
    new_b = sub.rhs().substitute(x=b)     ## Rewrites b in terms of u
    du = diff(sub.rhs(),x)
    g(u) = (f(x)/du).substitute(solve_for_x(sub,x)).expand()
    return show(integrate(g(u),u,new_a, new_b, hold = true))

We can now use ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 10: \textbf{u_̲sub_with_bounds… to perform a u-substitution on the integral above with integrand $f(x) = 3x^2\sqrt{x^3 + 1}$ and $u = x^3 + 1$ and bounds $a = -1$ and $b = 1$.

def f(x):
    return 3*x^2 * sqrt(x^3 + 1)
u_sub_with_bounds(f, u == x^3 + 1, -1, 1)

We are able to solve this definite integral since we know the antiderivative of $\sqrt{u}$. $$\displaystyle \int_0^2 \sqrt{u} \ du = \dfrac{2}{3}u^{3/2} \biggr \rvert_0^2 = \dfrac{2}{3}(2^{3/2} - 0^{3/2}) = \dfrac{4\sqrt{2}}{3}.$$ We can use SageMath to verify our answer by using the $\textbf{integrate}$ command with our original integrand and bounds.

show(integrate(f(x),x,-1,1))

Example 4

Use the functions ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 10: \textbf{u_̲sub} and ParseError: KaTeX parse error: Expected 'EOF', got '_' at position 10: \textbf{u_̲sub_with_bounds… to simply the following integrals by using u-substitition. Then solve the integrals by hand using their simplified form. Lastly, use SageMath to verify that your answer is correct.

1. $\displaystyle \int (3x + 2)(3x^2 + 4x)^4 \ dx$

2. $\displaystyle \int \sqrt{x} \sin(x^{3/2} - 1) \ dx$

3. $\displaystyle \int 3x^5\sqrt{x^3 + 1}\ dx$

4. ParseError: KaTeX parse error: Got function '\sqrt' with no arguments as superscript at position 22: …aystyle \int_0^\̲s̲q̲r̲t̲{7} x(x^2 + 1)^…

5. $\displaystyle \int_0^{\pi/4} \left(1 + e^{\tan(x)}\right) \sec^2(x) \ dx$

6. $\displaystyle \int_e^{e^3} \dfrac{1}{x(\ln(x))^2} \ dx$