SCsub

#!/usr/bin/env python
from misc.utility.scons_hints import *

Import("env")

File = env.File

source_files = [
    File("display_server_x11.cpp"),
    File("key_mapping_x11.cpp"),
]

if env["use_sowrap"]:
    source_files.append(
        [
            File("dynwrappers/xlib-so_wrap.c"),
            File("dynwrappers/xcursor-so_wrap.c"),
            File("dynwrappers/xinerama-so_wrap.c"),
            File("dynwrappers/xinput2-so_wrap.c"),
            File("dynwrappers/xrandr-so_wrap.c"),
            File("dynwrappers/xrender-so_wrap.c"),
            File("dynwrappers/xext-so_wrap.c"),
        ]
    )

if env["vulkan"]:
    source_files.append(File("rendering_context_driver_vulkan_x11.cpp"))

if env["opengl3"]:
    env.Append(CPPDEFINES=["GLAD_GLX_NO_X11"])
    source_files.append(
        [
            File("gl_manager_x11_egl.cpp"),
            File("gl_manager_x11.cpp"),
            File("detect_prime_x11.cpp"),
            File("#thirdparty/glad/glx.c"),
        ]
    )

Return("source_files")