Book a Demo!
CoCalc Logo Icon
StoreFeaturesDocsShareSupportNewsAboutPoliciesSign UpSign In
torvalds
GitHub Repository: torvalds/linux
 Path: blob/master/arch/s390/net/bpf_timed_may_goto.S
29269 views
1
/* SPDX-License-Identifier: GPL-2.0 */

2


3
#include <linux/export.h>

4
#include <linux/linkage.h>

5
#include <asm/asm-offsets.h>

6
#include <asm/nospec-insn.h>

7


8
#define R2_OFF 0

9
#define R5_OFF (R2_OFF + (5 - 2 + 1) * 8)

10
#define R14_OFF (R5_OFF + 8)

11
#define RETADDR_OFF (R14_OFF + 8)

12
#define R15_OFF (RETADDR_OFF + 8)

13
#define BACKCHAIN_OFF (R15_OFF + 8)

14
#define FRAME_SIZE (BACKCHAIN_OFF + 8)

15
#define FRAME_OFF (STACK_FRAME_OVERHEAD - FRAME_SIZE)

16
#if (FRAME_OFF + BACKCHAIN_OFF) != __SF_BACKCHAIN

17
#error Stack frame layout calculation is broken

18
#endif

19


20
	GEN_BR_THUNK %r1

21


22
SYM_FUNC_START(arch_bpf_timed_may_goto)

23
	/*

24
	 * This function has a special ABI: the parameters are in %r12 and

25
	 * %r13; the return value is in %r12; all GPRs except %r0, %r1, and

26
	 * %r12 are callee-saved; and the return address is in %r0.

27
	 */

28
	stmg %r2,%r5,FRAME_OFF+R2_OFF(%r15)

29
	stg %r14,FRAME_OFF+R14_OFF(%r15)

30
	stg %r0,FRAME_OFF+RETADDR_OFF(%r15)

31
	stg %r15,FRAME_OFF+R15_OFF(%r15)

32
	lgr %r1,%r15

33
	lay %r15,-FRAME_SIZE(%r15)

34
	stg %r1,__SF_BACKCHAIN(%r15)

35


36
	lay %r2,0(%r12,%r13)

37
	brasl %r14,bpf_check_timed_may_goto

38
	lgr %r12,%r2

39


40
	lg %r15,FRAME_SIZE+FRAME_OFF+R15_OFF(%r15)

41
	lmg %r2,%r5,FRAME_OFF+R2_OFF(%r15)

42
	lg %r14,FRAME_OFF+R14_OFF(%r15)

43
	lg %r1,FRAME_OFF+RETADDR_OFF(%r15)

44
	BR_EX %r1

45
SYM_FUNC_END(arch_bpf_timed_may_goto)

46


47