Kerr_equatorial_geodesics.ipynb

Kernel: SageMath (stable)

Equatorial geodesics in Kerr spacetime

%display latex

The spacetime manifold and Boyer-Lindquist coordinates:

M = Manifold(4, 'M')
X.<t,r,th,ph> = M.chart(r"t r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\phi")
X

The spacetime metric:

g = M.lorentzian_metric('g')
var('m, a', domain='real')
rho2 = r^2 + (a*cos(th))^2
Delta = r^2 -2*m*r + a^2
g[0,0] = -(1-2*m*r/rho2)
g[0,3] = -2*a*m*r*sin(th)^2/rho2
g[1,1], g[2,2] = rho2/Delta, rho2
g[3,3] = (r^2+a^2+2*m*r*(a*sin(th))^2/rho2)*sin(th)^2
g.display()

u = M.vector_field('u')
var('eps', latex_name=r'\varepsilon')
var('ell', latex_name=r'\ell')
u[0] = ((r^2 + a^2*(1+2*m/r))*eps - 2*a*m/r*ell)/Delta
u[1] = sqrt(eps^2 - 1 + 2*m/r - (ell^2-a^2*(eps^2-1))/r^2 
            + 2*m/r^3*(ell-a*eps)^2)
u[3] = (2*a*m/r*eps + (1-2*m/r)*ell)/Delta
u.display_comp()

norm = g(u,u)
norm.coord_function()

Value of $g(u,u)$ in the equatorial plane ($\theta=\frac{\pi}{2}$):

norm.coord_function()(t,r,pi/2,ph)

nabla = g.connection()
print(nabla)

Levi-Civita connection nabla_g associated with the Lorentzian metric g on the 4-dimensional differentiable manifold M

The 4-acceleration vector $a = \nabla_{u}\, u$:

Du = nabla(u)
a = u.contract(0, Du, 1)
a.set_name('a')
a.display_comp()

Values of the 4-acceleration in the equatorial plane ($\theta=\frac{\pi}{2}$):

a[0](t,r,pi/2,ph)

a[1](t,r,pi/2,ph)

a[2](t,r,pi/2,ph)

a[3](t,r,pi/2,ph)

The (non-zero and non-redundant) Christoffel symbols in Boyer-Lindquist coordinates:

g.christoffel_symbols_display()