3D Plots in Sage on CoCalc

var('x y')
k = 2
plot3d(4 * sin(x) * cos(y) * exp(-0.1 * x^2), (x, -k*pi, k*pi), (y, -k*pi, k*pi), mesh=True)

var('x, y, z')
T = RDF(golden_ratio)
F = 2 - (cos(x+T*y) + cos(x-T*y) + cos(y+T*z) + cos(y-T*z) + cos(z-T*x) + cos(z+T*x))
r = 4.77
implicit_plot3d(F, (x,-r,r), (y,-r,r), (z,-r,r), plot_points=40, color='darkkhaki')

var('a k')
f(a, k) = a * e^k
implicit_plot3d(f(x, y) - z, (x,0,10), (y,0,10), (z, 0, 10))

var('u')
circle = (cos(u), sin(u))
revolution_plot3d(circle, (u,0,2*pi), axis=(2,1),  show_curve=True, opacity=0.5).show(aspect_ratio=(1,1,1))

var('u')
line = u
parabola = u^2
sur1 = revolution_plot3d(line, (u,0,1), opacity=0.5, rgbcolor=(1,0.5,0), show_curve=True, parallel_axis='x')
sur2 = revolution_plot3d(parabola, (u,0,1), opacity=0.5, rgbcolor=(0,1,0), show_curve=True, parallel_axis='x')
(sur1+sur2).show()

u = var('u')
f = u^2
revolution_plot3d(f, (u,0,2), axis=(1,0.2), show_curve=True, opacity=0.5, rgbcolor=(0,1,0)).show(aspect_ratio=(1,1,1))

var('u,v')
parametric_plot3d((cos(u), 2*sin(u)+cos(v), sin(v)), (u,0,2*pi), (v,-pi,pi), mesh=True)

x,y,z=var('x y z')
plot_vector_field3d((x*cos(z),-y*cos(z),sin(z)), (x,0,pi), (y,0,pi), (z,0,pi))

pi = float(pi)
m = matrix(RDF, 6, [sin(i^2 + j^2) for i in [0,pi/5,..,pi] for j in [0,pi/5,..,pi]])
list_plot3d(m, color='yellow', frame_aspect_ratio=[1, 1, 1/3], num_points=40, mesh=True, interpolation_type='clough')